Написание программы

       LIST p=16F84             ; PIC16F844 целевой процессор
       #include "P16F84.INC"    ; Включить файл заголовков
       CBLOCK 0x10              ; Временное хранилище
       state
       l1,l2
       ENDC
       org 0                    ; Начало вектора.
       goto setports            ; Переход к началу кода.
       org 4                    ; Вектор прерывания.
  halt goto halt                ; Задаём бесконечный цикл и ничего не делаем.
setports clrw                   ; Ноль в W.
       movwf PORTA              ; Убедимся, что PORTA обнулён, прежде чем использовать.
       movwf PORTB              ; Убедимся, что PORTB обнулён, прежде чем использовать.
       bsf STATUS,RP0           ; Выбираем Bank 1
       clrw                     ; Маскируем все биты для выхода.
       movwf TRISB              ; Устанавливаем регистр TRISB.
       bcf STATUS,RP0           ; Переключаемся к Bank 0.
initialise clrw                 ; Начальное состояние.
       movwf state              ; Устанавливаем его.
  loop call getmask             ; Конвертируем состояние в bitmask.
       movwf PORTB              ; Записываем его в порт.
       incf state,W             ; Увеличиваем на единицу состояние в W.
       andlw 0x04               ; Оборачиваем его.
       movwf state              ; Возвращаем в память.
       call wait                ; Ждем
       goto loop                ; И цикл
                                ; Функция возвращения bitmask для выхода порта для 
                                ; текущего состояния.
                                ; Верхний кусок содержит биты для одной установки 
                                ; света и
                                ; нижний кусок биты для другой установки. Бит 1 
                                ; красный, 2 жёлтый
                                ; а бит три зелёный. Бит четыре не используется.
getmask movf state,W            ; Берём статус в W.
      addwf PCL,F               ; Добавляем компенсацию в W для PCL для расчета. goto.
      retlw 0x41                ; state==0 это зелёный и красный.
      retlw 0x23                ; state==1 это жёлтый и красный/жёлтый.
      retlw 0x14                ; state==3 это красный и зелёный.
      retlw 0x32                ; state==4 это красный/жёлтый и жёлтый.
                                ; Функция, использующая два цикла для реализации паузы.
wait movlw 5
     movwf l1
w1 call wait2
     decfsz l1
     goto w1
     return
wait2 clrf l2
w2 decfsz l2
     goto w2
     return
     END